簡介

　　性能是一個很重要的特征。你需要事先設(shè)計好性能指標，否則日后就要為此重新編寫程序。就是說：要設(shè)想好怎樣最佳化地執(zhí)行ASP程序？

　　本文提出了一些優(yōu)化ASP應(yīng)用和VBScript的技巧，許多技巧和缺陷都經(jīng)過了研討。這里列出的建議已經(jīng)在http://www.microsoft.com 和其他站點上進行了測試，都工作得非常好。本文假設(shè)你具備ASP開發(fā)的基本知識，包括VBScript或者JScript，ASP應(yīng)用程序，ASP Session，以及其他ASP內(nèi)置對象（Request，Response和Server）。

　　通常，ASP的執(zhí)行性能遠遠不僅僅依賴ASP代碼本身！在本文的尾部列出了與性能相關(guān)的資源，它們含概了ASP和非ASP的部分，包含ActiveX Data Objects（ADO），Component Object Model（COM），數(shù)據(jù)庫（Database），以及Internet信息服務(wù)器（IIS）的配置。除了這些，還有一些非常好的鏈接值得你一看。

技巧1：在Web服務(wù)器上緩存經(jīng)常使用的數(shù)據(jù)

　　典型的情況是：ASP頁面從后臺存儲中取回數(shù)據(jù)，然后以超文本標記語言（HTML）的形式形成結(jié)果。不管數(shù)據(jù)庫的速度如何，從內(nèi)存中取回數(shù)據(jù)要比從后臺存儲設(shè)備中快得多。從本地硬盤讀取數(shù)據(jù)通常也非?？臁Ｋ?，提高性能可以通過緩存服務(wù)器上的數(shù)據(jù)來實現(xiàn)，無論是將數(shù)據(jù)緩存在內(nèi)存中，或者本地硬盤中。

　　緩存是經(jīng)典的“空間換時間”的折中方式。如果緩存得恰當，就可以看到顯著的性能提升。為了讓緩存有效，必須保證緩存數(shù)據(jù)是經(jīng)常要重用的，而且也是計算起來繁瑣的。裝滿陳舊數(shù)據(jù)的緩存是對內(nèi)存的浪費。

　　不經(jīng)常改變的數(shù)據(jù)是緩存的較好對象，因為不需要隨時考慮這些數(shù)據(jù)更新后的同步操作。組合框、參考表格、DHTML代碼、擴展標記語言串、菜單以及站點配置變量（包括數(shù)據(jù)源名字DSNS，Internet協(xié)議地址IP以及Web路徑）都是很好的緩存對象。注意：要緩存數(shù)據(jù)表達式而不是數(shù)據(jù)本身。如果一個ASP頁面經(jīng)常變化并且很費力去緩存（比如整個產(chǎn)品目錄），就要考慮預(yù)產(chǎn)生HTML，而不是每次發(fā)生請求時再描述它。

技巧2：在Application或Session對象中緩存經(jīng)常使用的數(shù)據(jù)

　　ASP中的Application和Session對象是在內(nèi)存中緩存數(shù)據(jù)的便利容器。你可以將數(shù)據(jù)賦值給Application和Session對象，這些數(shù)據(jù)在HTTP調(diào)用期間將一直保持在內(nèi)存中。Session中的數(shù)據(jù)是為每一個用戶服務(wù)的，Application中的數(shù)據(jù)是所有用戶共享的。

　　何時需要在Application和Session中裝入數(shù)據(jù)？通常，當應(yīng)用程序啟動或者會話開始時，數(shù)據(jù)就被裝入了。為了在這時裝入數(shù)據(jù)，在Application OnStart()或者Session OnStart()中分別添加適當?shù)拇a。這些函數(shù)位于文件Global.asa中，如果原來不存在，就添加上。也可以在數(shù)據(jù)首次需要的時候調(diào)入，在ASP頁面中添加代碼，檢查數(shù)據(jù)是否存在，如果沒有發(fā)現(xiàn)，就調(diào)入它。這里有一個例子，它代表了被稱為“l(fā)azy evalution”的經(jīng)典性能處理技術(shù)：直到需要時，再去計算。例子如下：

<%

Function GetEmploymentStatusList

 Dim d

 d = Application("EmploymentStatusList")

 If d = "" Then

 ' FetchEmploymentStatusList function (not shown)

 ' fetches data from DB, returns an Array

 d = FetchEmploymentStatusList()

 Application("EmploymentStatusList") = d

 End If

 GetEmploymentStatusList = d

End Function

%>

對于不同的數(shù)據(jù)，可以編寫類似的函數(shù)代碼。

　　數(shù)據(jù)應(yīng)該按什么格式保存？任何變量類型都可以，因為所有的腳本變量都是不同的。比如說，可以保存為字符串、整型或者數(shù)據(jù)。通常，將ADO記錄集的內(nèi)容存儲到這些變量類型中一個。為了從ADO記錄集中取出數(shù)據(jù)，需要手工地拷貝數(shù)據(jù)到VBScript變量中，每次一個字段。使用任意一個ADO記錄集的函數(shù)functions GetRows(),GetString() 或者 Save() (ADO 2.5)都非常得快速而且簡單，這里有個函數(shù)，描述了如何使用GetRows（）返回記錄集數(shù)據(jù)的數(shù)組：

' Get Recordset, return as an Array

Function FetchEmploymentStatusList

 Dim rs 

 Set rs = CreateObject("ADODB.Recordset")

 rs.Open "select StatusName, StatusID from EmployeeStatus", _

 "dsn=employees;uid=sa;pwd=;"

 FetchEmploymentStatusList = rs.GetRows() " Return data as an Array

 rs.Close

 Set rs = Nothing

End Function

上述代碼的一個更深的技巧是為列表緩存了HTML。下面是個簡單的例子：

' Get Recordset, return as HTML Option list

Function FetchEmploymentStatusList

 Dim rs, fldName, s

 Set rs = CreateObject("ADODB.Recordset")

 rs.Open "select StatusName, StatusID from EmployeeStatus", _

 "dsn=employees;uid=sa;pwd=;"

 s = "<select name=""EmploymentStatus">" & vbCrLf

 Set fldName = rs.Fields("StatusName") ' ADO Field Binding

 Do Until rs.EOF

 ' Next line violates Don't Do String Concats,

 ' but it's OK because we are building a cache

 s = s & " <option>" & fldName & "</option>" & vbCrLf

 rs.MoveNext

 Loop

 s = s & "</select>" & vbCrLf

 rs.Close

 Set rs = Nothing ' See Release Early

 FetchEmploymentStatusList = s ' Return data as a String

End Function

在合適的環(huán)境下，可以在Application或者Session中緩存ADO記錄集本身，但是有2點提示：

• ADO必須是自由線程標記的
  
• 需要使用disconnected recordset方式

　　如果不能保證上述2個條件，就不要緩存ADO記錄集，因為這會產(chǎn)生很大的危險性。

　　當在Application或Session中保存數(shù)據(jù)后，數(shù)據(jù)將一直保持，除非程序改變它、Session變量到期或者Web應(yīng)用程序重新啟動。如果數(shù)據(jù)需要更新，怎么辦？可以調(diào)用只有管理員才能訪問的ASP頁面來更新數(shù)據(jù)，或者，通過函數(shù)周期性的自動更新數(shù)據(jù)。下面的例子中，與緩存數(shù)據(jù)一起保存了時鐘標記，過一段時間后，就刷新數(shù)據(jù)。

<%

' error handing not shown...

Const UPDATE_INTERVAL = 300 ' Refresh interval, in seconds

' Function to return the employment status list

Function GetEmploymentStatusList

 UpdateEmploymentStatus

 GetEmploymentStatusList = Application("EmploymentStatusList")

End Function

' Periodically update the cached data

Sub UpdateEmploymentStatusList

 Dim d, strLastUpdate

 strLastUpdate = Application("LastUpdate")

 If (strLastUpdate = "") Or _

 (UPDATE_INTERVAL < DateDiff("s", strLastUpdate, Now)) Then

 ' Note: two or more calls might get in here. This is okay and will simply

 ' result in a few unnecessary fetches (there is a workaround for this)

 ' FetchEmploymentStatusList function (not shown)

 ' fetches data from DB, returns an Array

 d = FetchEmploymentStatusList()

 ' Update the Application object. Use Application.Lock()

 ' to ensure consistent data

 Application.Lock

 Application("EmploymentStatusList") = d

 Application("LastUpdate") = CStr(Now)

 Application.Unlock

 End If

End Sub

　　必須意識到，在Session或者Application對象中緩存大容量的數(shù)組不是一個好的方法。存取數(shù)組中任何元素前，腳本語言的規(guī)則要求首先要建立整個數(shù)組的臨時備份。比如，如果在Application對象中緩存一個100，000個元素的數(shù)組，其中包含U.S.郵政編碼與本地氣象站的對應(yīng)關(guān)系，ASP就必須首先拷貝所有100，000個氣象站信息到臨時數(shù)組中，然后才能選擇其中一個字符串進行處理。在這種情況下，創(chuàng)建一個定制的組件，編寫一個方法存儲氣象站信息，是非常好的方法。

技巧3：在Web服務(wù)器磁盤上緩存數(shù)據(jù)和HTML頁面

　　有時候，有“許多”數(shù)據(jù)要在內(nèi)存中緩存?！霸S多”是相對而言的，它取決于能消耗多少內(nèi)存、緩存項目的數(shù)量以及取回數(shù)據(jù)的頻度。任何情況下，如果需要在內(nèi)存中緩存大量的數(shù)據(jù)，請考慮以text或者XML文件格式在Web服務(wù)器硬盤上做緩存。當然，也可以混合使用硬盤緩存數(shù)據(jù)以及內(nèi)存緩存數(shù)據(jù)，從而達到最佳緩存。

　　注意：當測試一個單一ASP頁面的性能時，從磁盤取回數(shù)據(jù)不一定比從網(wǎng)絡(luò)數(shù)據(jù)庫中取回數(shù)據(jù)快，但是緩存減少了網(wǎng)絡(luò)數(shù)據(jù)庫的調(diào)用。在大規(guī)模調(diào)用時，這將明顯地提高網(wǎng)絡(luò)的吞吐能力。緩存一個費時的查詢結(jié)果是非常有用的，比如對于一個復(fù)雜的存儲過程，或者大量的結(jié)果數(shù)據(jù)。

　　ASP和COM提供了幾種建立基于磁盤緩沖配置的工具。ADO記錄集的Save（）和 Open（）函數(shù)負責保存和調(diào)入磁盤上的記錄集。另外還有一些組件：

• Scripting.FileSystemObject 允許你創(chuàng)建、讀取和寫文件
  
• MSXML，Microsoft XML 解析器隨Internet Explorer而來，支持保存和裝入XML文檔
  
• LookupTable對象（比如在MSN上使用）是從磁盤調(diào)入簡單列表的很好選擇。

　　最后，考慮緩存磁盤數(shù)據(jù)的表達式，而不是數(shù)據(jù)本身。預(yù)處理的HTML可以存儲為.htm或者.asp文件，鏈接直接指向它們。使用諸如XBuilder或者Microsoft SQL Server Internet發(fā)布類的商業(yè)工具，能夠自動處理這些過程。而且，也可以在.asp文件中包含HTML程序片斷。同樣，也可使用FileSystemObject從磁盤上讀取HTML文件，或者使用XML for early rendering來做這個工作。

技巧4：避免在Application或Session對象中緩存非輕快型組件

　　在Application或Session對象中緩存數(shù)據(jù)是一個很好的方法，但是，緩存COM對象卻有嚴重的缺陷。在Application或Session對象中緩存經(jīng)常使用的COM對象這個工作是非常吸引人的，但是很不幸，許多COM對象，包括用Visual Basic 6.0或者以前版本編寫的對象組件，當存儲在Application或Session對象中后，都會產(chǎn)生嚴重的瓶頸問題。

　　特別地，當組件編寫得不是很輕巧時，就極可能產(chǎn)生瓶頸問題。一個輕型組件就是標記了ThreadingModel=Both的組件，其中合計了自由線程的排列（FTM），或者標記了ThreadingModel=Neutral（Neutral模式是Windows2000和COM＋中的新特征）。下面的組件不是輕型的：

• Free-threaded組件（除非被集合成FTM）
  
• Apartment-threaded組件
  
• Single-threaded組件

　　Configured components不是輕型組件，除非它們是Neutral-threaded的。Apartment-threaded組件和其他非輕型組件在頁范圍內(nèi)工作得很好，就是說，它們是在一個單一ASP頁面中創(chuàng)建并釋放的。

　　如果緩存了非輕型組件，將會發(fā)生什么錯誤？在Session對象中緩存的非輕型組件將會“鎖住”會話。ASP維護著一個響應(yīng)請求的工作線程池，通常，新的請求被第一個可用的工作線程控制。如果一個會話被鎖在一個線程中，那么請求就被迫等待到相關(guān)的線程變?yōu)榭捎?。這里有一個類比：你前往一個超級市場，挑選了一些食品，并在3號付款臺付款。從那以后，只要在那個超級市場買食品付款，你就會經(jīng)常到3號付款臺去，雖然其他的付款臺人少些甚至沒有人。

技巧5：不要在Application或Session對象中緩存數(shù)據(jù)庫連接

　　緩存ADO連接通常不是一個好的策略。如果一個連接對象被存儲在Application對象中，并在所有的頁面使用，那么所有頁面將會爭奪該連接的使用。如果存儲在ASP Session對象中，那么將要為每一個用戶都打開數(shù)據(jù)庫連接。這將挫敗連接池的使用意圖，并且在Web服務(wù)器和數(shù)據(jù)庫上都施加了不必要的高代價壓力。

　　為了替代緩存數(shù)據(jù)庫連接，可以在使用ADO的每個ASP頁面中創(chuàng)建并釋放ADO對象。這將非常有效，因為IIS擁有內(nèi)建的數(shù)據(jù)庫連接池。更準確地說，IIS自動處理OLEDB和ODBC連接池，這將保證在每個頁面創(chuàng)建并且釋放連接的工作高效進行。

　　由于連接的記錄集存儲了數(shù)據(jù)庫連接的參考，所以，不要在Application或Session對象中緩存連接的記錄集。然而，可以安全地緩存disconnected類型的記錄集，它們并不保存相應(yīng)數(shù)據(jù)庫連接的參考。為了斷開記錄集，執(zhí)行下面2步：

 Set rs = Server.CreateObject("ADODB.RecordSet")

 rs.CursorLocation = adUseClient ' step 1

 ' Populate the recordset with data

 rs.Open strQuery, strProv

 ' Now disconnect the recordset from the data provider and data source

 rs.ActiveConnection = Nothing ' step 2

　　更多的關(guān)于連接池的信息請訪問 ADO and SQL Server。

技巧6：聰明地使用Session對象

　　Session在繁忙站點上使用時有幾個缺陷。繁忙的意思是：站點上每秒有上百的頁面被請求，或者同時有上千的訪問用戶。這個技巧對于那些要求水平擴展強的站點非常重要，也就是指這些站點：它們利用多個服務(wù)器完成數(shù)據(jù)裝載或者處理大量容錯。對于小型站點，比如內(nèi)部網(wǎng)Intranet，Session是非常值得提倡的。

　　再次重申，ASP自動地為每一個首次點擊Web服務(wù)器的用戶創(chuàng)建一個Session，每一個Session占有大約10KB的內(nèi)存，生存期默認是20分鐘。

　　使用Session最大的問題不是性能，而是擴展性，Session不能跨越多個Web服務(wù)器，一旦在一個服務(wù)器上創(chuàng)建了Session，它的數(shù)據(jù)就駐留在那里。這意味著，如果在Web上使用Session，你就得為每一個直接訪問存放Session服務(wù)器的用戶請求設(shè)計一個策略。這就是將用戶“粘”在Web服務(wù)器上，術(shù)語“sticky sessions”就來源于此。如果Web服務(wù)器遇到障礙，“Stuck”用戶就會丟失他們的Session狀態(tài)，因為Session不保留在磁盤上。

　　執(zhí)行粘性session的策略包括硬件與軟件解決方式，比如windows2000高級服務(wù)器中的 Network Load Balancing 以及Cisco公司的Local Director，但換取這些要犧牲一定的擴展性。

　　Application對象也不能跨越服務(wù)器。如果需要在Web群中共享并更新Application數(shù)據(jù)，就需要使用后臺數(shù)據(jù)庫。然而，只讀Application數(shù)據(jù)在Web群中仍然很有用。

　　許多對任務(wù)要求嚴格的站點都要設(shè)立至少2個Web服務(wù)器，所以在設(shè)計嚴格任務(wù)的應(yīng)用程序時，就需要執(zhí)行“sticky sessions”，或者簡單地避免使用Session，同時也可以采取其他保存用戶狀態(tài)到獨立Web服務(wù)器的管理技術(shù)。

　　如果不使用Session，一定要確認將它們關(guān)閉，這可以通過Internet服務(wù)管理器實現(xiàn)。如果決定使用Session，可以通過幾種方法來最小化它們的影響。

　　可以將不需要Session的內(nèi)容（比如幫助畫面，訪問者區(qū)域，等等）移動到關(guān)閉Session的獨立ASP應(yīng)用程序中。在基礎(chǔ)頁面上，可以給ASP一個指示，讓它不需要使用Session。將下面的代碼直接加入到ASP頁面的頭部：
  

<% @EnableSessionState=False %>

　　使用這個指示的一個很好的解釋是在框架結(jié)構(gòu)中Session創(chuàng)建了一個有趣的問題。ASP確保在一個時刻只有一個來自Session的請求被執(zhí)行，這就確保了如果瀏覽器為單個用戶請求多個頁面時，只有一個ASP請求在那時能夠接受Session，如此就避免了存取Session對象時的多線程問題。很不幸，在框架結(jié)構(gòu)中的所有頁面將按照連續(xù)的順序顯示出來，一個接一個，而不是同時，所以用戶為了看到整個框架必須要等很長時間。規(guī)則是：如果一定的框架頁面沒有使用Session，就一定要告訴ASP直接使用@EnableSessionState=False。

　　除了使用Session對象，還有許多其他管理會話狀態(tài)的選擇。對于小數(shù)量的狀態(tài)（小于4KB），我們通常建議使用cookie、查詢字符串變量以及表單隱藏域。對于象購物車一樣的大數(shù)量數(shù)據(jù)，后臺數(shù)據(jù)庫是最合適的選擇。

技巧7：將代碼裝入COM對象中

　　如果要編寫很多VBScript或者JScript，為了提個性能，可以將代碼編寫成COM對象并且編譯使用。編譯代碼基本上比解釋性代碼運行快許多，編譯組件對象可通過“early binding”存取其他COM對象，這比在腳本中調(diào)用組件要有效。

這么做有許多優(yōu)點：

• COM對象有益于從商業(yè)規(guī)則中獨立出表達式規(guī)則
  
• COM對象使代碼重用變?yōu)榭赡?
  
• 許多開發(fā)者發(fā)現(xiàn)用VB，C＋＋或者Visual J＋＋編寫程序，比ASP更容易調(diào)試

　　COM對象也有缺點，包括初始開發(fā)時間和對不同編程技巧的需要。注意將少量ASP代碼做成COM對象組件不會有好處，反而可能導(dǎo)致性能的損失，從而失去了編譯代碼的優(yōu)勢。怎樣組合使用ASP腳本和COM對象達到最佳性能是一個測試的問題。我們注意到微軟公司已經(jīng)大規(guī)模在Windows 2000/IIS 5.0上提高了腳本與ADO的性能，由此，隨著IIS5.0版本的引進，減少了編譯代碼的性能優(yōu)勢。

技巧8：使用Option Explicit

　　要在ASP文件中使用Option Explicit定義，并且放置到ASP文件的頭部，從而強迫開發(fā)者在使用前聲明所有的變量。許多程序員都認為這在應(yīng)用程序調(diào)試時非常有用，因為它避免了產(chǎn)生錯誤類型變量以及偶然創(chuàng)建新變量的可能。

也許更重要的是，聲明的變量要大大快于非聲明變量。

技巧9：拷貝經(jīng)常使用的數(shù)據(jù)到腳本變量中

　　在ASP中存取COM對象時，應(yīng)該拷貝經(jīng)常使用的對象數(shù)據(jù)到腳本變量中，這樣就減少了對COM對象的方法調(diào)用。這些調(diào)用要比存取腳本變量相對來說費時費力。當存取Collection和Dictionary對象時，使用這項技巧也減少了昂貴的查找操作。

　　通常，如果要不止一次地存取對象數(shù)據(jù)，就應(yīng)將數(shù)據(jù)放入腳本變量中，對象數(shù)據(jù)主要也就是Request變量（表單和查詢字符串變量）。比如，站點要傳遞一個叫做UserID的查詢字符串變量，假設(shè)它將在一個特殊頁面被引用12次，那么不需要調(diào)用Request（“UserID”）12次，只要在ASP頁面的頭部分配給UserID一個變量，然后在頁面中使用它，這樣做就節(jié)省了11次COM方法的調(diào)用。

　　實際中，存取COM屬性或方法是很昂貴的，下面的例子展示了通用代碼：

Foo.bar.blah.baz = Foo.bar.blah.qaz(1)
If Foo.bar.blah.zaq = Foo.bar.blah.abc Then ' ...

上面的代碼執(zhí)行后，發(fā)生以下事情：

1、變量Foo被當作全局對象
2、變量bar被當作Foo的一員
3、變量blah被當作Foo.bar的一員
4、變量qaz被當作Foo.bar.blah的一員
5、調(diào)用Foo.bar.blah.quaz(1)
6、再執(zhí)行步驟1到3分解baz
7、分解baz做為Foo.bar.blah的一員
8、再執(zhí)行步驟1到3分解zaq
9、再執(zhí)行步驟1到3一次分解abc

如上所示，這非常沒有效率并且很慢。更快的方法是用VBScript編寫代碼，如下：

Set myobj = Foo.bar.blah ' do the resolution of blah ONCE
Myobj.baz = myobj.qaz(1)
If Myobj.zaq = Myobj.abc Then '...

如果使用VBScript 5.0或者更高版本，可以用With語句編寫：

With Foo.bar.blah

 .baz = .qaz(1)

 If .zaq = .abc Then '...

 ...

End With

注意：這個技巧也可以應(yīng)用在VB編程中。

技巧10：避免再定義數(shù)組

　　爭取不要再定義數(shù)組?？紤]到性能問題，如果機器的物理內(nèi)存大小不夠，最好按最差情況或者最佳情況設(shè)置數(shù)組的初始尺寸，需要時再重新定義。

下面的代碼展示了Dim和Redim的使用：

< %
Dim MyArray()
Redim MyArray(2)
MyArray(0) = "hello"
MyArray(1) = "good-bye"
MyArray(2) = "farewell"
...
' some other code where you end up needing more space happens, then ...
Redim Preserve MyArray(5)
MyArray(3) = "more stuff"
MyArray(4) = "even more stuff"
MyArray(5) = "yet more stuff"
% >

　　簡單地定義數(shù)組初始尺寸為合適的大小是非常好的，而不要用Redim加大數(shù)組。這么做也許浪費了一些內(nèi)存（如果沒有完全地使用空間），但是贏得了速度。

技巧11：使用Response Buffering

　　通過打開“response buffering”可以緩沖一個值得輸出的整個頁面內(nèi)容，這將最小化輸出到瀏覽器的數(shù)據(jù)量，從而提高了整體性能。每一次輸出都耗費許多，所以寫得越少，效果越好。TCP/IP在發(fā)送少量大的數(shù)據(jù)包時，要比發(fā)送大量小的數(shù)據(jù)包工作效率高，因為它是慢速啟動并不斷發(fā)送的。

　　有2種方法打開Response Buffering。首先，可以使用Internet Services Manager為整個應(yīng)用程序打開response buffering，這是推薦的方式，而且在IIS4.0和IIS5.0中，默認狀態(tài)下，response buffering是打開的。其次，在每一頁面上，可以在頭部放置如下代碼開打開response buffering：

< % Response.Buffer = True % >

　　這段代碼必須在任何數(shù)據(jù)輸出到瀏覽器前被執(zhí)行（就是說，在任何html內(nèi)容顯示前和在任何cookie被設(shè)置前）。通常情況下，為整個應(yīng)用程序打開response buffering是很好的方案，這么做后就不用在每個頁面頭部設(shè)置如上的代碼。

　　關(guān)于打開response buffering的一個通用問題是：用戶必須要等待整個頁面全部產(chǎn)生后，才能看到內(nèi)容。對于一個長時間運行的頁面來說，可以設(shè)置Response.Buffer=False關(guān)閉緩沖。然后，好的策略是利用Response.Flush方法，它將輸出所有已被ASP描述的HTML內(nèi)容到瀏覽器。比如，在描述了一個1，000行表格的100行后，ASP就可以使用Response.Flush來強迫輸出這100行的內(nèi)容到瀏覽器，這時用戶就可以看到前100行數(shù)據(jù)，同時其余的行數(shù)據(jù)正在準備生成。

　　注意，關(guān)于上面的1，000行表格輸出的例子，對于一些瀏覽器器來說，除非遇到< /table >標記，它們不會輸出表格的任何內(nèi)容。如果這樣，可以將表格分割成許多含有少量行的多個表格，然后在每一個表格產(chǎn)生后，調(diào)用Response.Flush輸出。新版的Internet Explorer在整個表格下載后才顯示內(nèi)容，并且，如果定義了表格的列寬度，生成表格的速度將特別快。

關(guān)于打開response buffering的另外一個問題是：當生成非常大的頁面時，將消耗非常大的服務(wù)器內(nèi)存。

技巧12：批處理單行腳本和Response.Write命令

　　VBScript語法< % = expression % >的意思是輸出expression的數(shù)值。如果response buffering沒有打開，每個這樣的語句將按照許多小數(shù)據(jù)包的形式輸出數(shù)據(jù)到瀏覽器，這將降低程序性能。因此，請使用下面的技巧：替換緊挨著的多個一行表達式調(diào)用為一個調(diào)用，用Response.Write名稱輸出。比如，在下面的例子中，對于每行每個字段的輸出，只有一個寫操作：

<table>

<% For Each fld in rs.Fields %>

 <th><% = fld.Name %></th>

<%

Next 

While Not rs.EOF

%>

 <tr>

 <% For Each fld in rs.Fields %>

 <td><% = fld.Value %></td>

 <% Next 

 </tr>

 <% rs.MoveNext 

Wend %>

</table>

下面是更有效率的代碼，每行一個輸出：

<table>

<%

 For each fld in rs.Fields

 Response.Write ("<th>" & fld.Name & "</th>" & vbCrLf)

 Next

 While Not rs.EOF

 Response.Write ("<tr>")

 For Each fld in rs.Fields %>

 Response.Write("<td>" & fld.Value & "</td>" & vbCrLf)

 Next

 Response.Write "</tr>"

 Wend

%>

</table>

　　當response buffering關(guān)閉時，這個技巧非常得有用。最好是打開response buffering，這樣就可以看到批量的Response.Wwrite是如何提高了程序性能。

技巧13：使用< OBJECT >標記引用對象

　　如果需要引用除代碼路徑外的對象（尤其是服務(wù)器、Application范圍的對象），請在Global.asa文件中使用
< object runat=server id=objname >標記來定義它們，而不要使用Server.CreateObject方法。使用Server.CreateObject方法可以立即創(chuàng)建對象，這樣如果隨后不使用它，就浪費了資源。使用
< object id=objname >標記可以定義對象objname，但是直到它的屬性或者方法首次使用時，objname才實際創(chuàng)建。

技巧14：避免在循環(huán)中串聯(lián)字符串

許多人在循環(huán)中建立一個字符串，就象下面的樣子：

s = "<table>" & vbCrLf

For Each fld in rs.Fields

 s = s & " <th>" & fld.Name & "</th> "

Next

While Not rs.EOF

 s = s & vbCrLf & " <tr>"

 For Each fld in rs.Fields

 s = s & " <td>" & fld.Value & "</td> "

 Next

 s = s & " </tr>"

 rs.MoveNext

Wend

s = s & vbCrLf & "</table>" & vbCrLf

Response.Write s

　　這存在幾個問題。首先是重復(fù)的連接字符串消耗二次方的時間，而且，運行的時間與計算的字段數(shù)量也是平方的關(guān)系。下面的簡單例子更清楚地說明這一點：

s = ""

For i = Asc("A") to Asc("Z")

 s = s & Chr(i)

Next

　　在第1層循環(huán)時，S的值是“A”;第2層循環(huán)時，VBScript要重新分配字符串，拷貝了2個字符（“AB”）到S中;第3層循環(huán)時，需要再重新分配并且拷貝3個字符到S中。在第N層循環(huán)時，就需要重新分配并拷貝N個字符到S中。那就是1+2+3+...+N的總和，也就是N*（N＋1）/2個拷貝。

　　在上面的記錄集例子中，如果有100個記錄和5個字段，內(nèi)部循環(huán)就要執(zhí)行100*5＝500次，并且，完成所有拷貝和再分配任務(wù)的時間將接近500*500＝250，000。這還是一個適當尺寸記錄集的拷貝工作。

　　在這個例子中，可以通過替換字符串連接為Response.Write（）或者行內(nèi)腳本（< % =fld.Value % >）的方法提高程序性能。如果response buffering打開（也應(yīng)該打開），這將很快，因為Response.Write僅僅附加數(shù)據(jù)在緩沖區(qū)的尾部，而且不需要再分配。

　　如果用JScript連接字符串，強烈建議使用“＋＝”操作符，就是說，使用s＋＝“字符串”，而不是s ＝ s＋“字符串”。

技巧15：打開瀏覽器和代理的緩沖

　　默認情況下，ASP禁止了瀏覽器和代理的緩沖功能。如果有一個每次都不要更新的頁面，就應(yīng)該打開瀏覽器和代理的緩沖，這將允許瀏覽器和代理在一段時間內(nèi)使用該頁面的“緩沖”拷貝數(shù)據(jù)。緩沖能夠大大地減輕服務(wù)器的數(shù)據(jù)轉(zhuǎn)載量，并提高用戶的瀏覽性能。

哪些類別的動態(tài)頁面適合被緩存呢？下面是一些例子：

• 天氣頁面，每5分鐘更新一次
  
• 新聞或版本列表頁面，每天更新2次

　　注意：使用瀏覽器或者代理緩存后，對Web服務(wù)器的點擊次數(shù)就會減少。如果想精確地了解所有頁面，或者對于郵遞廣告，就不適于使用瀏覽器和代理緩存了。

　　瀏覽器緩存由HTTP“Expires”頭參數(shù)控制，它由Web服務(wù)器發(fā)送給瀏覽器。ASP提供了2個簡單的方法發(fā)送這個頭部參數(shù)。設(shè)置頁面在未來一定時間內(nèi)到期，可以使用Response.Expires屬性。下面的例子將告訴瀏覽器內(nèi)容在10分鐘后過期：

< % Response.Expires = 10 % >

　　設(shè)置Response.Expires為負數(shù)或者0，就禁止了緩存。對第2個屬性Response.ExpiresAbsolute的設(shè)置，允許指定在一個特殊時間到來時內(nèi)容過期。

< % Response.ExpiresAbsolute = #May 31,2001 13:30:15# % >

　　除了使用Response對象來設(shè)置到期時間，還可以在HTML文件頭部寫< META >標記。盡管代理不會注意到這個標記，但是一些瀏覽器可以。

< META HTTP-EQUIV="Expires" VALUE="May 31,2001 13:30:15" >

　　最后，對于HTTP代理，使用Response.CacheControl可以指示是否緩存內(nèi)容。設(shè)置屬性為“Public”，打開代理緩存內(nèi)容的功能。

< % Response.CacheControl = "Public" % >

　　默認情況下，這個屬性是設(shè)置成“Private”的。注意：不要讓代理緩沖那些顯示給特定用戶的頁面，因為代理可能會將屬于其他用戶的頁面送給當前用戶。

技巧16：在任何可能時使用Server.Transfer，而不要用Response.Redirect

　　Response.Redirect告訴瀏覽器請求另一個不同的頁面，這常常用于引導(dǎo)用戶到登錄頁面或者出錯處理頁面。由于重定向強迫了一個新頁面請求，結(jié)果是瀏覽器必須要與Web服務(wù)器循環(huán)2次，并且Web服務(wù)器必須處理一個額外的請求。IIS5.0引進了一個新功能Server.Transfer，它執(zhí)行在同一服務(wù)器上的頁面?zhèn)鬏?，這將避免額外的瀏覽器－Web服務(wù)器的數(shù)據(jù)循環(huán)，形成良好的系統(tǒng)性能，對于用戶也有較好的響應(yīng)時間。

技巧17：避免使用服務(wù)器變量

　　存取服務(wù)器變量導(dǎo)致Web站點建立一個特殊的請求并收集所有的服務(wù)器變量，而并不是你要求的那個變量。這類似于在文件夾中取回一個特殊的文件，要想取回一個文件，就得首先獲取所在文件夾的信息。

　　不要存取非法的Request對象（比如Request（"Data"）），對于那些不在Request.Cookies、Request.Form、Request.QueryString或者Request.ClientCertificate中的項目，隱含就指向了Request.ServerVariables變量，而這些變量要比其他集合對象慢得多。

技巧18：調(diào)整Web服務(wù)器

　　有幾個IIS調(diào)整參數(shù)可以提高站點性能。比如，對于IIS4.0，我們經(jīng)常發(fā)現(xiàn)提高ASP ProcessorThreadMax參數(shù)能夠產(chǎn)生重大的效果，特別是在那些要等待后臺資源比如數(shù)據(jù)庫或中間件產(chǎn)品的站點。在IIS5.0中，你可以發(fā)現(xiàn)調(diào)整ASP線程通道要比調(diào)整AspProcessorThreadMax效果更佳。

最佳的配置設(shè)定取決于應(yīng)用程序代碼、支持的硬件設(shè)備以及客戶端的工作量。發(fā)現(xiàn)最佳配置的唯一方法就是測試。