在VB編程的時候，很多人肯定碰到過開啟程序以后程序界面會“沒反應(yīng)”，“沒有響應(yīng)”，但是我們代碼要求執(zhí)行的任務(wù)還在正常的進行，任務(wù)執(zhí)行完畢，程序界面又恢復(fù)正常，尤其是使用循環(huán)的時候很容易出現(xiàn)程序沒響應(yīng)的現(xiàn)象，這類問題怎么解決呢？用DoEvents就可以解決。舉例：

Private Sub DelayTime(num As Long)
Dim star, ends As Long
star = timeGetTime
ends = star
Do While ends - star < num
ends = timeGetTime
DoEvents
Loop
End Sub

DoEvents 是： 轉(zhuǎn)讓控制權(quán)，以便讓操作系統(tǒng)處理其它的事件。最簡單的理解，比如你要在某個耗時很多的過程中（最常見的是循環(huán)），還要響應(yīng)某個操作－比如控制進度條的顯示，那就需要加入DoEvents
但是，當看到這句話時，腦子里面的概念很模糊，只有一個淺薄的認識。打個比方：如果現(xiàn)在有一個從1 到100000000的循環(huán)，有一點編程常識的人肯定知道在這個耗時較長的循環(huán)過程中，基本上是不能進行別的操作（當然不排除一些特別的情況），但是因為某些特別的要求，你要在循環(huán)過程中，進行其他操作，這時DoEvents 就派上用場了。
現(xiàn)在，大家應(yīng)該明白了DoEvents 的主要功能了吧。下面舉一些實例（基本上都是轉(zhuǎn)載的），當然建議自己能親自去試驗，理解會深一些。

(注: '** 后面的代碼表示如果在該處用了這個語句 以下代碼中用到了一些api函數(shù),請用vb附帶的api瀏覽器查閱) （轉(zhuǎn)載）

一. 基本用法:
1.窗體啟動時如果要處理的事務(wù)太多或者用sleep函數(shù)暫停,造成其很久都不能出現(xiàn)時怎么辦?
例如代碼:
Private Sub Form_Load()
Show
'DoEvents
Sleep 5000
End Sub
通常容易想到在sleep前加個show,但還是不能達到預(yù)想的效果,窗體雖然出來了,但好象只達到了一半,如果加上第3句,將看到效果大不相同

2.如果有個很耗時的循環(huán)導(dǎo)致程序不響應(yīng),怎么辦?
例如:
Dim L As Long
For L = 1 To 1000000
'DoEvents
Next L
如果無'DoEvents，在循環(huán)過程中程序無法處理事件，對于用戶來說是不響應(yīng)，無法控制的

3.想在循環(huán)中看到處理過程?
同樣:
Dim L As Long
For L = 1 To 10000
'DoEvents
Text1.Text=Cstr(l)
Next L
無'DoEvents時將無法看到text1中的變化,而只在循環(huán)結(jié)束時看到最后結(jié)果

4.怎樣中止循環(huán)?
如果有:
Private Sub Command3_Click()
Dim L As Long
Do
L = L + 1
Debug.Print L
DoEvents
Loop
End Sub
會發(fā)現(xiàn)當關(guān)閉窗口后，debug中的數(shù)據(jù)仍然在變化，說明并沒結(jié)束
需要如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do While DoEvents
If IsExit = True Then Exit Do
L = L + 1
Loop
End Sub

Private Sub Command2_Click()''或者在form_unload模塊中等等
IsExit = True
End Sub
其中 isexit是全局變量
有些人喜歡用end語句來結(jié)束程序，小程序固然可以，但當太大，或者調(diào)用了某些特殊的api函數(shù)后可能導(dǎo)致預(yù)想不到的錯誤。如果裝載了許多東西在程序結(jié)束時不處理將卸載很慢，而且這種做法也極不符合正規(guī)軟件的要求。總之end語句毛病很多，此不詳談，建議少使用甚至不使用。

二. 其基本用法大概就這些,現(xiàn)在解析其中的一些[難點]

1.為什么還是不能結(jié)束?
代碼如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do
If IsExit = True Then Exit Do '句0
DoEvents '** 句1
Text1.Text = CStr(L) '** 句2
L = L + 1
Loop
End Sub

Private Sub Form_Load()
Static N As Long
N = N + 1
MsgBox N
End Sub

Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub

運行結(jié)果：啟動時msg顯示1，點擊command1，text1在變化。此時再點form右上角的小差(關(guān)閉窗體)，發(fā)現(xiàn)vb運行控制上的按扭并沒變化，說明程序還在運行。如果編譯成程序后運行，按下ctrl+del+alt也可發(fā)現(xiàn)它還沒結(jié)束。通過讀代碼，并沒發(fā)現(xiàn)錯誤，怎么回事?

關(guān)鍵在于 句2 訪問了控件的屬性
代 碼運行路徑：當在DoEvents時，程序釋放控制權(quán)，可以接收事件消息，form-unload事件只能從此處產(chǎn)生，假設(shè)此時關(guān)閉form，unload事件發(fā)生，即DoEvents后就運行unload代碼，得到isexit=t,并且form卸載，代碼返回到DoEvents之后，運行 句2，注意現(xiàn)在form 已經(jīng)卸載了，text1從哪里來呢？

于是form重新裝載，代碼跳到form_load模塊運行，所以在關(guān)閉窗體后可以看到msg 顯示2，此模塊運行完后再繼續(xù)句2后面的代碼，當下次循環(huán)遇到 句0時退出循環(huán)

另：既然退出了循環(huán)，怎么還不能結(jié)束？
vb程序規(guī)定(其實其他的windows語言一樣)：窗體卸載時并不是立即卸載其模塊代碼，而只先卸載窗體中的控件和一些屬性值，程序中最后一個窗體卸載時才完全卸載。
在這個單窗體程序中，form卸載時因為循環(huán)的控制無法卸載代碼，失去了卸載代碼的機會，導(dǎo)致再也不能卸載(因為沒卸載代碼,所以運行的 句2 是并不會出錯)

另：既然再次運行了form_load代碼，怎么看不見窗體？
因為程序啟動時窗體的到顯示的消息，而只運行此模塊并沒有(如果在msgbox n語句前加上show,就可以看到它了)
如何解決?
通過以上分析，應(yīng)該很簡單，把句1 和句2調(diào)換一下就可以了，關(guān)鍵：
<仔細分析代碼是如何運行的,避免在form已經(jīng)卸載了情況下訪問控件>

2.用了DoEvents速度太慢了怎么辦?
DoEvents的代價是速度變慢，但要程序響應(yīng)又不得不用
其實DoEvents語句允許任何應(yīng)用程序執(zhí)行相關(guān)事件，而不僅僅是你自己的程序，所以變得很慢。
可以讓它響應(yīng)本程序事件動作，需要用到api函數(shù)GetInputState
例如用: If GetInputState() Then DoEvents  '來代替DoEvents可使循環(huán)運行更快

3.既要同時響應(yīng)事件又要控件不變化，怎么辦?
例如在一個長的循環(huán)中向listview控件中添加記錄，無DoEvents時程序無響應(yīng)，但有它時控件又閃的厲害
解決辦法：
a.不一定每次循環(huán)都DoEvents，可以在適當時間時才用，至少沒那么閃
b. 應(yīng)用api函數(shù) ValidateRect ，功能是使指定的矩型區(qū)域生效，通知Windows不對指定的區(qū)域進行重畫
另：InvalidateRect 功能相反，同時需要用到函數(shù) GetClientRect 取得指定對象的矩形區(qū)域應(yīng)用*rect函數(shù)指定listview的矩形區(qū)不重畫，即可避免閃爍(但還是要注意恢復(fù)重畫，否則看不見了真實效果)

4.控時循環(huán)和變速齒輪
請看下面的代碼：
Option Explicit
Private Declare Function timeGetTime Lib "winmm.dll" () As Long
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
Dim Kt As Long
IsExit = False
Do
Kt = timeGetTime()
'do something
L = L + 1
Text1.Text = L
'DoEvents '句 1
While timeGetTime - Kt < 50 '句 2
'While Abs(timeGetTime - Kt) < 50 '句 3
'While Abs(timeGetTime - Kt) And (Not IsExit) < 50 '句 4

DoEvents '句 5
Wend
'DoEvents '句 6
If IsExit Then Exit Do
Loop
End Sub

Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub
其中可用的代碼(除去加"'" 號的代碼)就是通常的控時循環(huán)代碼
運行代碼并不會出現(xiàn)錯誤，但在循環(huán)過程，請開啟變速齒輪看看
當關(guān)閉齒輪時，將發(fā)現(xiàn)text1.text停止了，別慌，等一段時間它又會繼續(xù)(這要看你設(shè)定的時間，這里是50毫秒，如果設(shè)定的太長text1.text將半天都沒變化，這是怎么回事?
變速齒輪在啟動時將hook.dll映射到你的程序地址運行，更改了timegettime()函數(shù)獲取的時間
如果在句2和句3間插入debug.print timegettime,timegettime-kt 將發(fā)現(xiàn)，在關(guān)閉齒輪的瞬間后者變成了負值，timegettime變小了，所以才造成需要等很久
如果是編寫游戲，而用戶開了齒輪，那可就慘了

解決方案：
a.用句3代替句2，這個方法最簡便，雖然不符實，但不會出問題，建議使用
b.不要句5，換用句6(這樣就能達到效果嗎?) 因為齒輪還是從DoEvents語句運行時才能插的進來，所以只要kt=timegettime 和 timegettime之間沒有DoEvents就不會出錯
ab.兩種方法都有些小問題，但無大礙DoEvents有興趣者請自己分析

5.程序怎么"死了"?
這只是一些人編寫時沒注意到的小問題，提醒一下：
同樣用上面的代碼，如果設(shè)定的時間太短，以至在代碼運行到句2時已經(jīng)超時了，句5將不能運行了，當然程序就死了哦，以防萬一，加上句1，所以此時也只能用a方案來解決齒輪的問題了
有必要用句4代替句3 嗎? 除非你設(shè)定的時間太長，人家想關(guān)閉你的程序要等上好半天。